Today I am showing a very simple document locking class. If you don’t care about Object Orientated code in LotusScript or you’ve seen enough examples… feel free to move along.

What is the class?

This is a very simple class to assist with document locking. There are so many ways to do locking in Lotus Notes, but I use this one because it’s quick and easy.

What do I need besides the class?

The only thing this class needs is a view. I’ve put all of the parameters of the view in the Constants section of my script library:

Const LOCK_VIEW = "($$Lock)"
Const LOCK_FORM = "zzLock"
Const LOCK_USERFIELD = "username"
Const LOCK_UNIDFIELD = "unid"
Const LOCK_DELETEVAL = "~~DELETEME~~"

The selection formula of the view is “form = “zzLock”" and it has two columns: unid and username.

What’s the huge flaw in your code?

I couldn’t figure out how to use this class with a group who has Author access but not create document rights. Luckily… I’ve never had to deal with that situation. Any ideas would be appreciated.

How do you use the class in a form or agent?

Here’s an example of what I do in the QueryModeChange event of a form.

Sub Querymodechange(Source As Notesuidocument, Continue As Variant)
	Dim locktool As New LockTools
	Dim lockname As String
	Dim result As Integer
	Dim workspace As New NotesUIWorkspace
	Dim session As New notessession

	If source.EditMode = False Then
		LockName = LockTool.isDocLockedStr(source.document)
		If LockName <> "" And LockName <> session.CommonUserName Then
			Msgbox("This document is currently locked by " + LockName + ".")
			continue = False
			Exit Sub
		End If
		Call locktool.lockdoc(source.Document)
	End If
End Sub

Here’s the corresponding QueryClose of the document:

Sub Queryclose(Source As Notesuidocument, Continue As Variant)
		' if doc is in edit mode... try and delete the locks
	Dim locktool As New locktools
	If source.EditMode Then
		Call LockTool.unLockDoc(source.document)
	End If
End Sub

Script Library Code

'libLockTools: 

Option Public
Option Declare
%INCLUDE "lsconst.lss"
' The only scenario this can't handle is if the user has Author but not "Create Documents" role. 

Const LOCK_VIEW = "($$Lock)"
Const LOCK_FORM = "zzLock"
Const LOCK_USERFIELD = "username"
Const LOCK_UNIDFIELD = "unid"
Const LOCK_DELETEVAL = "~~DELETEME~~"

Class LockTools
	Private lockView As NotesView
	Private userCanCreate As Boolean
	Private userCanDelete As Boolean
	Private userAccessLevel As Long

	Sub New()
		Dim session As New NotesSession
		If (session.CurrentDatabase.QueryAccessPrivileges(session.UserName) And DBACL_CREATE_DOCUMENTS) > 0 Then
			userCanCreate = True
		Else
			userCanCreate = False
		End If

		If (session.CurrentDatabase.QueryAccessPrivileges(session.UserName) And DBACL_DELETE_DOCUMENTS) > 0 Then
			userCanDelete = True
		Else
			userCanDelete = False
		End If

		userAccessLevel = session.CurrentDatabase.CurrentAccessLevel

	End Sub

	Function isDocLockedStr(doc As NotesDocument) As String
		Call init()
		Dim entry As NotesViewEntry

		Set entry = lockView.GetEntryByKey(doc.UniversalID,True)

		If entry Is Nothing Then
			isDocLockedStr = ""
		Else
			isDocLockedStr = entry.ColumnValues(1) ' this code is up for debate. but this is fast and easy
		End If

	End Function

	Function lockDoc(doc As NotesDocument) As Boolean
		' debating this code. Do I return false if the user can't create docs?
		If userCanCreate = False Then
			LockDoc = True
			Exit Function
		End If

		lockdoc = False
		If isDocLockedStr(doc) = "" Then
			Dim session As New notessession
			Dim newLockDoc As NotesDocument
			Dim authorsItem As NotesItem
			Set newLockDoc = session.CurrentDatabase.CreateDocument
			Set authorsItem = New NotesItem( newLockDoc,"DocAuthors", session.UserName,AUTHORS)

			newLockDoc.form = LOCK_FORM
			Call newLockDoc.ReplaceItemValue(LOCK_UNIDFIELD,doc.UniversalID)
			Call newLockDoc.ReplaceItemValue(LOCK_USERFIELD,session.UserName)
			newLockDoc.Save True,False
			lockdoc = True
			Print "Document Successfully Locked"
		End If

	End Function

	Function unLockDoc(doc As NotesDocument) As Boolean
		unLockDoc = False
		Dim entries As NotesViewEntryCollection
		Call init()
		Set entries = lockView.GetAllEntriesByKey(doc.UniversalID)
		If userCanDelete = True Then
			entries.RemoveAll(True)
			unLockDoc = True
		Else
			Call entries.StampAll(LOCK_UNIDFIELD,LOCK_DELETEVAL)
		End If

		Print "Document Successfully Unlocked"
	End Function

	Function unLockAllDocs As Boolean
		unLockAllDocs = False
		Dim entries As NotesViewEntryCollection
		Call init()

		Set entries = lockView.AllEntries
		entries.RemoveAll(True)
		unLockAllDocs = True
	End Function

	Sub init()
		If lockView Is Nothing Then
			Dim session As New notessession
			Set lockView = session.CurrentDatabase.GetView(LOCK_VIEW)
			If lockView Is Nothing Then
				Error 9003, "Cannot find Lock View"
			End If
		End If
	End Sub

End Class

Why not just have functions in a Script Library?

I could have put all of the functions you see in a Script Library. One thing I like about Classes is that they are distinct. I can take this Class and add it to any form without worrying if I’m overwriting the “unlockdoc” routine.

Also, what if we want to keep the locks in a different database? You could extend the class: Class AdvancedLockTools as LockTools and rewrite the init() function.

What’s next?

What’s next for this code? I want to try and come up with a way to get Authors who cannot create documents to work.

This is such a simple example of a class. I have a reporting tool that uses classes to represent “columns” of data. Each column type (Number, text, date, name, etc… ) extends from a base class. The power of classes is evident when I put columns in a list and loop through the columns and calling a function (e.g. getData() or getFormatting()) that is different in each column.

I hope to provide some of these complex examples in the future. Object Oriented coding can be used in almost all of the languages we use as Notes developers (JavaScript, Java, and LotusScript).

A description from the jsCrypto site:

We offer a fast, small symmetric encryption library written in Javascript. Though several such libraries exist, jsCrypto offers several advantages.

• A clean, simple interface to basic AES encryption/decryption, as well as OCB and CCM modes for authenticated encryption
• A cryptographic random number generator that collects randomness from user mouse movements, among other sources
• jsCrypto is at least four times faster in all browsers and about 12% smaller than the best previously existing implementation
• In Internet Explorer, jsCrypto is 11 times faster than the fastest previous existing implementation

I’m going to say right now… that with unlimited resources (aka time and money) this application should be rewritten. I wouldn’t even promise that I would re-do it in Lotus Notes. But that’s another story.

The application now has a long list of enhancements. One enhancement (our favorite), is a requirement to create a relational reporting system of the data. All of the data (minus the rich-text fields). Many other requirements call for interfacing with other systems at the company. Some might be Web Services but a lot of the transactions (I think) are done in TIBCO.

My friend (bless his heart) is sold on an idea. His idea is to (somehow) create a LIVE SQL Server back-end to this data. Basically, on the open and save of the data… it will all be sync’ed to a Microsoft SQL Server (DB2 is not in the company and is not an option).

I’m trying to see it his way but I really have no experience with something like this. I’ve offloaded Notes data to reporting databases before but I’ve never loaded and saved ALL of the data to/from an external system. I have so many doubts running through my mind.

Have you guys done this? How feasible is it to take an existing (a big fat one… I mean like orca fat) application and move the data to SQL Server while keeping the Notes Client interface? Is this something for DECS?

I appreciate any suggestions. I’m at a loss for trying to convince him to try a different path.

The NotesDocumentCollection in R8 now has four new fabulous methods: Merge, Contains, Intersect, Subtract.

• Merge: Adds to a document collection any documents not already in the collection that are contained in a second collection.
• Contains: Indicates whether or not a NotesDocumentCollection contains all of the given NotesDocuments or all of the NotesDocuments associated with the given ViewEntries.
• Intersect: Removes from a document collection any documents not also contained in a second collection.
• Subtract: Removes from a document collection any documents contained in a second collection.

This is the best part… each method takes a variant called inputNotes as a parameter. The parameter can be a String, NotesDocument, NotesDocumentCollection, NotesViewEntry or NotesViewEntryCollection. Talk about versatility!

These new methods allow the NotesDocumentCollection object to be a “container” tool and not just a “document access” tool. Great job Lotus!

The reason the Evaluate is faster is because the @DbLookup gets values from a view index, without having to loop through and access each document. In contrast, pulling values using GetAllDocumentsByKey requires you to loop through and access each document.

That’s great but writing Evaluate strings for DBLookup and DBColumn calls isn’t exactly fun. So… I decided to wrap the calls in a handy class.

To call the code is pretty easy:

use "libLSViewTools"

Dim tools as New LSViewTools
dim result as variant

'** function call is DBlookup(server As String,database As String,
'** view As String,key As String,pickMe As Variant,exactMatch As Boolean) As Variant

result = tools.DBLookup("myserver","mydatabase.nsf","myview","myfield",true)
print result(0)

result = tools.DBColumn("myserver","mydatabase.nsf","myview",1)
print result(0)

The parameter “pickme” in the dblookup function is a variant because I allow a number (column) or string (field name) to be sent (just like @DBLookup).

The lss file can be downloaded here: libLSViewTools.lss

The full code is here for your perusal:

'libLSViewTools: 

'***** libLSViewTools
'* Library with on class LSViewTools.
'* Class LSViewTools currently has two functions: DBlookup and DBColumn. Refer to the the Notes help
'* for a description of the formula equivalents

Option Public
Option Declare
%INCLUDE "lsconst.lss"

Class LSViewTools
	Private boolPrintErrors As Boolean
	Private boolThrowErrors As Boolean

	Sub New()
		boolPrintErrors = True
		boolThrowErrors= False
	End Sub

	Property Set printErrors As Boolean
		boolPrintErrors = printErrors
	End Property

	Property Set throwErrors As Boolean
		boolThrowErrors = throwErrors
	End Property

	Function DBlookup(server As String,database As String,view As String,key As String,pickMe As Variant,exactMatch As Boolean) As Variant
		Dim session As New NotesSession
		Dim evalBuilder As String
		Dim exactMatchStr As String
		Dim result As Variant

		On Error Goto error_proc
' Start Validation
		If view = "" Then
			Error 7000, "View cannot be null"
		End If

		If Typename(pickme) <> "STRING" And Typename(pickme) <> "INTEGER" Then
			Error 7001, "5th Parameter must be type string or integer."
		End If

		If server <> "" And database = "" Then
			Error 7003, "Database cannot be null if the server is specified"
		End If

		If exactMatch = False Then
			exactMatchStr = ";[PARTIALMATCH]"
		Else
			exactMatchStr = ""
		End If

		If server = "" And database <> "" Then
			server = session.CurrentDatabase.Server
		End If

		If Typename(pickme) = "STRING" Then
			evalBuilder = {@DbLookup("";@Name([CN];"}+ server + {"):"} + database + {";"} + view + {";"} + key + {";"} + pickme + {"} + exactMatchStr + {);}
		Else
			evalBuilder = {@DbLookup("";@Name([CN];"}+ server + {"):"} + database + {";"} + view + {";"} + key + {";} + pickme + exactMatchStr + {);}
		End If

		result = Evaluate(evalBuilder)

		If Isarray(result) Then
			dblookup = result
		Else
			dblookup = Evaluate("NULL")
		End If

		Exit Function
error_proc:
		If boolPrintErrors Then
			Print "LSViewTools " + Cstr(Getthreadinfo(LSI_THREAD_PROC)) + " Error: " + Cstr(Err) + " " + Error + ""
		End If
		If boolThrowErrors Then
			Error 7554, "LSViewTools " + Cstr(Getthreadinfo(LSI_THREAD_PROC)) + " Error: " + Cstr(Err) + " " + Error + ""
		End If
		DBLookup = Evaluate("NULL")
		Exit Function
	End Function

	Function DBColumn(server As String,database As String,view As String,column As Integer) As Variant
		Dim session As New NotesSession
		Dim evalBuilder As String
		Dim exactMatchStr As String
		Dim result As Variant

		On Error Goto error_proc
' Start Validation
		If view = "" Then
			Error 7000, "View cannot be null"
		End If

		If server <> "" And database = "" Then
			Error 7003, "Database cannot be null if the server is specified"
		End If

		If server = "" And database <> "" Then
			server = session.CurrentDatabase.Server
		End If

		evalBuilder = {@DbColumn("";@Name([CN];"}+ server + {"):"} + database + {";"} + view + {";} + Cstr(column) + {);}

		result = Evaluate(evalBuilder)

		If Isarray(result) Then
			If Cstr(result(0)) = "1.#INF" Then
				Error 7010, "DBColumn returned too many values"
			End If

			dbColumn = result
		Else
			dbColumn = Evaluate("NULL")
		End If

		Exit Function
error_proc:
		If boolPrintErrors Then
			Print "LSViewTools " + Cstr(Getthreadinfo(LSI_THREAD_PROC)) + " Error: " + Cstr(Err) + " " + Error + ""
		End If
		If boolThrowErrors Then
			Error 7555, "LSViewTools " + Cstr(Getthreadinfo(LSI_THREAD_PROC)) + " Error: " + Cstr(Err) + " " + Error + ""
		End If
		DbColumn = Evaluate("NULL")
		Exit Function
	End Function

End Class

Ed: “My Yellow Sons and Daughters, I am Ed Brill”

Yellow person: “Ed Brill is seven feet tall”

Ed: “Yes, I’ve heard! And if he were here, he’d consume Microsoft with fireballs from his eyes…and bolts of lightning from his arse! I AM Ed Brill! And I see, a whole army of my people.”

Sorry… that’s where my mind was at the moment. But then I saw a slide about LotusLive and I started dreaming about the “cloud.” The LotusLive product hosts collaboration applications like Lotus Sametime, Lotus Notes, and Connections. These applications are core Lotus products but what about the real “strength” behind Lotus (for the past 10+ years)? Custom applications.

I quickly popped into my old “There’s an app for that” mindset. I thought how great it would be if Lotus allowed for custom applications to be selected and added by customers into their LotusLive environment. Like the Apple App store. The applications would obviously have to go through a vetting process like Apple Iphone applications. I can’t imagine the process would be cheap or easy.

Wouldn’t it be great if IBM presented LotusLive to a company and said “We have this great online store full of custom applications. With one click of a button you can have this IdeaJam application installed in your environment. Check out the HR tools section of the store… it has many applications to fit your needs.”

It’s a pipe dream… but that’s where my head during Kevin’s speech.

p.s. I loved IamLUG. I hope they do it again. I’ve attended one Lotusphere and it was overwhelming. IamLUG was perfect.

EDIT: Nathan Freeman posted something similar in his popular blog and folks seemed to like it.

• We (the app) will save roughly $100,000 year (I say roughly because it is only calculated supply costs)
• We’ve eliminated the need to print to 3,000,000+ sheets of paper a year (I’ve estimated that to be 40 trees a year)
• They don’t give a dollar value but there is also significant monetary savings since we don’t have to transfer and store 3,000,000+ sheets of paper yearly.

I wish I could give more detail but I would probably have to talk to the PR department.

Need to automate your processes and stop using printers and faxes? There’s an app for that!

After reading Neil’s comment and going back to work I stared at my workspace for a moment. With all of the tabs filled with icons… I said to myself “There’s an app for that.”

Why is the iPhone so successful? C’mon… It’s just a cell phone. The reason for the  iPhone’s success  is small, inexpensive, and easy-to-install applications that are driving iPhone sales exponentially. The iPhone’s current slogan says it all: “There’s an app for that!”

Compare that to Lotus Domino. It’s just an email system. Or… is it an environment where you can build small (you can argue size if you want), inexpensive, and easy-to-install applications?

I was looking at my workspace and thinking about all of the applications I have built over the years (at too many different jobs).

• Do you need an underwriting system for loans? There’s an app for that.
• Do you need a workflow application to handle 100,000 faxes a quarter? There’s an app for that.
• Do you need a HR timesheet system? There’s an app for that.
• Do you need a Customer Relationship Management system? There’s an app for that.
• Do you need a sales pipeline application? There’s an app for that.
• Do you need a reference library for your sales team? There’s an app for that.
• Do you need 101 different call tracking applications? There’s 101 apps for that.
• Do you need a complete extranet with a content management system? There’s an app for that.

I could go on for pages. All of these systems were built on Lotus Notes/Domino. Some of these applications were created by the departments and we’ve inherited and maintained them over the years. Some of these applications (like the underwriting apps) turned into large systems (which Lotus Notes is very capable of handling).

I’ve met countless developers who just do whatever their manager or project manager instructs them to do. Because of Domino environment, I’ve spent the last ten years in direct contact with customers automating their processes, destroying legacy paper systems, and saving money.

Can other programming environments do the same thing? Of course! It’s just that their environments are not as adept at building small, inexpensive, and easy-to-install applications as Lotus Domino.

I might have even gone so far as recommending that Ed do the “developer dance” patented by Microsoft’s Steve Ballmer.

I believe the Notes Designer should be available to every Lotus Notes user. Restrict their access to production/dev servers… but allow end-users to tinker with their applications locally.

My company (typically) does not provide end-users with the designer client but recently (especially with the cost-cutting measures) my group has been quite busy. After listening to the business case for one person to start modifying his group’s application, I convinced my manager to let them get the designer and modify their Notes application locally. When the user is ready, I copy the items from their database and paste them into a test copy in the test environment.

So far I have been amazed with the development skills of the end user. Except for one issue (green/bold form headers) the code looks great. He followed all of the best practices and it was well-tested by the users.

Their application was old (I built it five years ago) and it needed work. Without the extra end-user development they might have looked for a different (non-Lotus Notes) solution. Allowing the end-user to tinker with their own application was a win/win for both teams.

When the Lotus Notes email client was crappy, user development and the benefits of workflow are what made Lotus Notes strong. Why not just return the designer back to the end users and watch productivity (and sales) soar?

For a long time I have wondered if the disturbing lack of Lotus Notes shops is just a Milwaukee issue. I finally decided to stop wondering and do a little research. I decided to use a very (un)scientific method… search Monster.com.

My searches were simple. I searched for the word “Lotus” in Milwaukee. The search found six results (jobs). Yikes! Chicago looked a bit better with 29 jobs and New York City looked great with 55 jobs.

Case solved! There are plenty of other Lotus Notes shops in other cities! I shouldn’t have FUD (Fear, Uncertainty, & Doubt) about Lotus Notes.

Then I got curious… what is the percentage of Lotus Notes jobs compared to jobs that contain the keyword “Outlook.” My results were a bit frightening.

To be fair… this data is terribly unreliable. For instance… doing a search for the word “sales” in Milwaukee returns 470 jobs. Many employers must not list their email system in the job description. Maybe companies that use Lotus Notes figure the software is easy enough to use so it is not listed as a job requirement.

Would I use these numbers to claim I know the market-share of Outlook vs Lotus Notes? No… I would not. Do these numbers worry me? Yes.